Greg Hellings
e4c678833b
Get rid of the numtide shell, as it doesn't have any good support for shellHook. Also, directly create the pre-commit check so that we can leverage its resulting bits in the packages. We now will have acces to things like pre-commit-config.yaml in the folder structure
105 lines
3.1 KiB
Nix
105 lines
3.1 KiB
Nix
# github.com/brianmcgee has lots of great ideas for going above and beyond for this
|
|
{
|
|
description = "Greg's homepage";
|
|
inputs = {
|
|
nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
|
|
flake-parts.url = "github:hercules-ci/flake-parts";
|
|
flake-root.url = "github:srid/flake-root";
|
|
hooks.url = "github:cachix/git-hooks.nix";
|
|
naersk.url = "github:nix-community/naersk";
|
|
};
|
|
|
|
outputs =
|
|
{ flake-parts, ... }@inputs:
|
|
flake-parts.lib.mkFlake { inherit inputs; } {
|
|
imports = [ inputs.flake-root.flakeModule ];
|
|
flake = {
|
|
# Universal things
|
|
# final: prev:
|
|
overlays.default = _final: _prev: { };
|
|
};
|
|
systems = [
|
|
"x86_64-linux"
|
|
"aarch64-linux"
|
|
"aarch64-darwin"
|
|
];
|
|
perSystem =
|
|
{ pkgs, self', ... }@inputs':
|
|
let
|
|
naersk-lib = pkgs.callPackage inputs.naersk { };
|
|
in
|
|
{
|
|
_module.args.pkgs = import inputs.nixpkgs {
|
|
inherit (inputs') system;
|
|
overlays = [ ];
|
|
};
|
|
devShells.default = pkgs.mkShell rec {
|
|
# These commands will be shown in the motd that users read
|
|
# upon entering the shell
|
|
inputsFrom = with pkgs; [
|
|
expat
|
|
fontconfig
|
|
freetype
|
|
freetype.dev
|
|
libGL
|
|
pkg-config
|
|
xorg.libX11
|
|
xorg.libXcursor
|
|
xorg.libXi
|
|
xorg.libXrandr
|
|
wayland
|
|
libxkbcommon
|
|
];
|
|
|
|
packages = with pkgs; [
|
|
cargo
|
|
clippy
|
|
pre-commit
|
|
rustc
|
|
rustfmt
|
|
stdenv.cc
|
|
];
|
|
|
|
buildInputs = self'.checks.pre-commit.enabledPackages;
|
|
|
|
shellHook =
|
|
let
|
|
lib_path = builtins.foldl' (a: b: "${a}:${b}/lib") "${pkgs.vulkan-loader}/lib" packages;
|
|
in
|
|
''
|
|
export LD_LIBRARY_PATH="${lib_path}"
|
|
''
|
|
+ self'.checks.pre-commit.shellHook;
|
|
};
|
|
|
|
checks = {
|
|
pre-commit = inputs.hooks.lib.${inputs'.system}.run {
|
|
src = ./.;
|
|
hooks = {
|
|
check-added-large-files.enable = true;
|
|
check-case-conflicts.enable = true;
|
|
check-merge-conflicts.enable = true;
|
|
check-symlinks.enable = true;
|
|
deadnix.enable = true;
|
|
end-of-file-fixer.enable = true;
|
|
fix-byte-order-marker.enable = true;
|
|
mixed-line-endings.enable = true;
|
|
nixfmt-rfc-style.enable = true;
|
|
trim-trailing-whitespace.enable = true;
|
|
# Rust hooks
|
|
cargo-check.enable = true;
|
|
clippy.enable = true;
|
|
rustfmt.enable = true;
|
|
};
|
|
};
|
|
};
|
|
|
|
# This is not special, this is just flakes
|
|
packages = rec {
|
|
default = rustpkg;
|
|
rustpkg = naersk-lib.buildPackage ./.;
|
|
};
|
|
};
|
|
};
|
|
}
|