Basic scaffolding

2025-02-24 10:14:02 -06:00
commit 7f92974785
8 changed files with 314 additions and 0 deletions
@@ -0,0 +1,92 @@
+# github.com/brianmcgee has lots of great ideas for going above and beyond for this
+{
+  description = "Greg's homepage";
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+    flake-parts.url = "github:hercules-ci/flake-parts";
+    flake-root.url = "github:srid/flake-root";
+    hooks.url = "github:cachix/git-hooks.nix";
+    naersk.url = "github:nix-community/naersk";
+  };
+
+  outputs =
+    { flake-parts, ... }@inputs:
+    flake-parts.lib.mkFlake { inherit inputs; } {
+      imports = [
+        inputs.flake-root.flakeModule
+      ];
+      flake = {
+        # Universal things
+        overlays.default = _final: _prev: { };
+      };
+      systems = [
+        "x86_64-linux"
+        "aarch64-linux"
+        "aarch64-darwin"
+      ];
+      perSystem =
+        { pkgs, self', ... }@inputs':
+        let
+          naersk-lib = pkgs.callPackage inputs.naersk { };
+        in
+        {
+          _module.args.pkgs = import inputs.nixpkgs {
+            inherit (inputs') system;
+            overlays = [ ];
+          };
+          devShells.default = pkgs.mkShell rec {
+            # These will just be available
+            packages = with pkgs; [
+              cargo
+              rustc
+              rustfmt
+              clippy
+              stdenv.cc
+              pre-commit
+            ];
+
+            buildInputs = self'.checks.pre-commit.enabledPackages;
+
+            RUST_SRC_PATH = pkgs.rustPlatform.rustLibSrc;
+
+            inherit (self'.checks.pre-commit) shellHook;
+            #  This is also used when building with iced
+            #  let
+            #    lib_path = builtins.foldl' (a: b: "${a}:${b}/lib") "${pkgs.vulkan-loader}/lib" packages;
+            #  in
+            #  ''
+            #    export LD_LIBRARY_PATH="${lib_path}"
+            #  ''
+          };
+
+          checks = {
+            pre-commit = inputs.hooks.lib.${inputs'.system}.run {
+              src = ./.;
+              excludes = [ ".*\\.txt" ];
+              hooks = {
+                check-added-large-files.enable = true;
+                check-case-conflicts.enable = true;
+                check-merge-conflicts.enable = true;
+                check-symlinks.enable = true;
+                deadnix.enable = true;
+                end-of-file-fixer.enable = true;
+                fix-byte-order-marker.enable = true;
+                mixed-line-endings.enable = true;
+                nixfmt-rfc-style.enable = true;
+                trim-trailing-whitespace.enable = true;
+                # Rust hooks
+                cargo-check.enable = true;
+                clippy.enable = true;
+                rustfmt.enable = true;
+              };
+            };
+          };
+
+          # This is not special, this is just flakes
+          packages = rec {
+            default = rustpkg;
+            rustpkg = naersk-lib.buildPackage ./.;
+          };
+        };
+    };
+}